Initial commit

buildSrc/build.gradle.kts

@@ -0,0 +1,7 @@
+plugins {
+	`kotlin-dsl`
+}
+
+repositories {
+	mavenCentral()
+}

buildSrc/settings.gradle.kts

@@ -0,0 +1,3 @@
+plugins {
+	id("dev.panuszewski.typesafe-conventions") version "0.9.0"
+}

buildSrc/src/main/kotlin/de.siphalor.smcmtk.plugin.gradle.kts

@@ -0,0 +1,43 @@
+plugins {
+	`java-gradle-plugin`
+	alias(libs.plugins.kotlin.jvm)
+	`maven-publish`
+}
+
+group = rootProject.group
+version = rootProject.version
+
+components {
+	java { withSourcesJar() }
+}
+
+tasks.jar {
+	manifest {
+		attributes["Implementation-Version"] = project.version
+	}
+}
+
+val siphalorMavenUser = project.property("siphalor.maven.user") as String?
+val siphalorMavenPassword = project.property("siphalor.maven.password") as String?
+publishing {
+	publications.withType<MavenPublication>() {
+		pom {
+			name = "Siphalor's Minecraft Modding Toolkit"
+			description = "Provides some general abstraction for easing the development of cross-version (Fabric) mod development.\n" +
+					"${project.description}"
+			url = "https://gitea.siphalor.de/Siphalor/smcmtk"
+		}
+	}
+	repositories {
+		if (siphalorMavenUser != null && siphalorMavenPassword != null) {
+			maven {
+				name = "siphalor"
+				url = uri("https://maven.siphalor.de/upload.php")
+				credentials {
+					username = siphalorMavenUser
+					password = siphalorMavenPassword
+				}
+			}
+		}
+	}
+}